qt5-mqtt/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Jan Peter Koenig <public@janpeterkoenig.com>
   3 # Contributor: Niklas <dev@n1klas.net>
   4
   5 pkgname=qt5-mqtt
   6 _qtver=5.15.2
   7 pkgver=${_qtver/-/}
   8 pkgrel=1
   9 pkgdesc="Module to implement MQTT protocol v3.1/3.1.1/5.0"
  10 arch=(x86_64)
  11 url="http://qt-project.org/"
  12 license=(GPL3 custom)
  13 depends=(qt5-base)
  14 makedepends=(git)
  15 source=("git://code.qt.io/qt/qtmqtt.git#tag=v$_qtver")
  16 sha512sums=('SKIP')
  17 _pkgfqn=${pkgname/5-/}
  18
  19 prepare() {
  20   mkdir -p build
  21 }
  22
  23 build() {
  24   cd build
  25   qmake ../$_pkgfqn
  26   make
  27 }
  28
  29 package() {
  30   cd build
  31   make INSTALL_ROOT="$pkgdir" install
  32
  33   # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
  34   find "$pkgdir"/usr/lib -type f -name '*.prl' \
  35     -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;
  36   install -Dm644 "$srcdir"/$_pkgfqn/LICENSE.GPL3-EXCEPT \
  37     "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.GPL3-EXCEPT
  38 }