bubblewrap/trunk/PKGBUILD

   1 # Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   2
   3 pkgbase=bubblewrap
   4 pkgname=(bubblewrap bubblewrap-suid)
   5 pkgver=0.8.0
   6 pkgrel=1
   7 pkgdesc='Unprivileged sandboxing tool'
   8 url='https://github.com/projectatomic/bubblewrap'
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(
  12   glibc
  13   libcap
  14 )
  15 makedepends=(
  16   bash-completion
  17   docbook-xsl
  18   git
  19   libxslt
  20   meson
  21 )
  22 _commit=4ab175fe6d3a4053444b04d805a6d686f53455b9  # tags/v0.8.0^0
  23 source=("git+$url#commit=$_commit")
  24 sha256sums=('SKIP')
  25
  26 pkgver() {
  27   cd $pkgbase
  28   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  29 }
  30
  31 prepare() {
  32   cd $pkgbase
  33 }
  34
  35 build() {
  36   arch-meson $pkgbase build -D selinux=disabled
  37   meson compile -C build
  38 }
  39
  40 check() {
  41   meson test -C build --print-errorlogs
  42 }
  43
  44 package_bubblewrap() {
  45   meson install -C build --destdir "$pkgdir"
  46 }
  47
  48 package_bubblewrap-suid() {
  49   pkgdesc+=" (setuid variant)"
  50   provides=("bubblewrap=$pkgver-$pkgrel")
  51   conflicts=(bubblewrap)
  52
  53   meson install -C build --destdir "$pkgdir"
  54   chmod u+s "$pkgdir/usr/bin/bwrap"
  55 }
  56
  57 # vim:set sw=2 sts=-1 et: