cairomm-1.16/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Kevin <kevin@archlinux.org>
   3 # Contributor: criminy <criminy@gmail.com>
   4
   5 pkgbase=cairomm-1.16
   6 pkgname=(cairomm-1.16 cairomm-1.16-docs)
   7 pkgver=1.16.1
   8 pkgrel=2
   9 pkgdesc="C++ bindings for Cairo"
  10 url="https://www.cairographics.org/cairomm/"
  11 arch=(x86_64)
  12 license=(LGPL MPL)
  13 depends=(cairo libsigc++-3.0)
  14 makedepends=(git meson mm-common)
  15 options=(!emptydirs)
  16 _commit=61286896d11ed961add217ff4a209d10d9efb700  # tags/1.16.1^0
  17 source=("git+https://gitlab.freedesktop.org/cairo/cairomm.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd cairomm
  22   git describe --tags | sed 's/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd cairomm
  27 }
  28
  29 build() {
  30   arch-meson cairomm build -D maintainer-mode=true
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package_cairomm-1.16() {
  39   depends+=(libsigc-3.0.so)
  40   provides=(libcairomm-1.16.so)
  41
  42   meson install -C build --destdir "$pkgdir"
  43
  44   # Split -docs
  45   mkdir -p docs/usr/share
  46   mv -t docs/usr/share "$pkgdir"/usr/share/{devhelp,doc}
  47 }
  48
  49 package_cairomm-1.16-docs() {
  50   pkgdesc+=" (documentation)"
  51   depends=()
  52   options=(!strip)
  53
  54   mv -t "$pkgdir" docs/*
  55 }