gnome-maps/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-maps
   5 pkgver=42.1
   6 pkgrel=1
   7 pkgdesc="A simple GNOME 3 maps application"
   8 url="https://wiki.gnome.org/Apps/Maps"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(geocode-glib geoclue gjs libchamplain libgee folks gfbgraph libhandy
  12          libgweather-4)
  13 makedepends=(gobject-introspection git meson yelp-tools)
  14 groups=(gnome)
  15 options=(debug)
  16 _commit=c71d614bef06d875841d21e82c1a547e8f154a91  # tags/v42.1^0
  17 source=("git+https://gitlab.gnome.org/GNOME/gnome-maps.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27 }
  28
  29 build() {
  30   arch-meson $pkgname build
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package() {
  39   meson install -C build --destdir "$pkgdir"
  40 }