gnutls/trunk/PKGBUILD

   1 # Maintainer: Jan de Groot <jgc@archlinux.org>
   2 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   3
   4 pkgname=gnutls
   5 pkgver=3.7.4
   6 pkgrel=2
   7 pkgdesc="A library which provides a secure layer over a reliable transport layer"
   8 arch=('x86_64')
   9 license=('GPL3' 'LGPL2.1')
  10 url="https://www.gnutls.org/"
  11 options=('!zipman' 'debug')
  12 depends=('gcc-libs' 'libtasn1' 'readline' 'zlib' 'nettle' 'p11-kit' 'libidn2'
  13          'libidn2.so' 'libunistring' 'brotli')
  14 checkdepends=('net-tools')
  15 optdepends=('guile: for use with Guile bindings')
  16 source=(https://www.gnupg.org/ftp/gcrypt/gnutls/v3.7/${pkgname}-${pkgver}.tar.xz{,.sig})
  17 sha256sums=('e6adbebcfbc95867de01060d93c789938cf89cc1d1f6ef9ef661890f6217451f'
  18             'SKIP')
  19 validpgpkeys=('462225C3B46F34879FC8496CD605848ED7E69871') # "Daiki Ueno <ueno@unixuser.org>"
  20
  21 build() {
  22   cd ${pkgname}-${pkgver}
  23   ./configure --prefix=/usr \
  24         --disable-static \
  25         --with-idn \
  26         --enable-openssl-compatibility \
  27         --enable-guile --with-guile-site-dir=no \
  28         --with-default-trust-store-pkcs11="pkcs11:"
  29 #       --enable-ktls \ # breaks testsuite
  30   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  31   make
  32 }
  33
  34 check() {
  35   cd ${pkgname}-${pkgver}
  36   make check
  37 }
  38
  39 package() {
  40   cd ${pkgname}-${pkgver}
  41   make DESTDIR="${pkgdir}" install
  42
  43   # lots of .png files are put into infodir and are gzipped by makepkg! this needs to be fixed by using !zipman
  44   # gzip -9 all files in infodir and manpages manually
  45   find "$pkgdir/usr/share/info" -name '*.info*' -exec gzip -n -9 {} \;
  46   find "$pkgdir/usr/share/man" -exec gzip -n -9 {} \;
  47 }