malcontent/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=malcontent
   4 pkgver=0.10.3
   5 pkgrel=2
   6 pkgdesc="Parental control support for applications"
   7 url="https://gitlab.freedesktop.org/pwithnall/malcontent"
   8 license=(LGPL2.1)
   9 arch=(x86_64)
  10 depends=(accountsservice dbus flatpak glib2 gtk3 polkit appstream-glib)
  11 makedepends=(git meson gobject-introspection gtk-doc libglib-testing yelp-tools)
  12 provides=(libmalcontent{,-ui}-${pkgver%%.*}.so)
  13 _commit=9dd47e5abcbddb8b08c29be0304ead70cee1c5bc  # tags/0.10.3^0
  14 source=("git+https://gitlab.freedesktop.org/pwithnall/malcontent.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24
  25   # Fix build with Meson 0.61
  26   # https://bugs.archlinux.org/task/73879
  27   git cherry-pick -n f433aaf8c8f82f0aeaedee664f08bc6fcad47b0d
  28 }
  29
  30 build() {
  31   arch-meson $pkgname build
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41   install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
  42 }