appstream-glib/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=appstream-glib
   5 pkgver=0.8.0
   6 pkgrel=1
   7 pkgdesc="Objects and methods for reading and writing AppStream metadata"
   8 url="https://people.freedesktop.org/~hughsient/appstream-glib/"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(gtk3 libyaml pacman gcab curl libstemmer)
  12 makedepends=(gobject-introspection gtk-doc git gperf meson)
  13 provides=(appdata-tools libappstream-glib.so)
  14 conflicts=(appdata-tools)
  15 replaces=(appdata-tools)
  16 options=(debug)
  17 _commit=fc9f22621846b0411173be176f06ea7c7a60b172  # tags/appstream_glib_0_8_0^0
  18 source=("git+https://github.com/hughsie/appstream-glib#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd $pkgname
  23   git describe --tags | sed 's/^appstream_glib_//;s/_/./g;s/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd $pkgname
  28
  29   # https://github.com/hughsie/appstream-glib/issues/445
  30   git cherry-pick -n 3870226a3585 8d3964003275 674490bd54ff
  31 }
  32
  33 build() {
  34   local meson_options=(
  35     -D alpm=true
  36     -D gtk-doc=true
  37     -D rpm=false
  38   )
  39
  40   arch-meson $pkgname build "${meson_options[@]}"
  41   meson compile -C build
  42 }
  43
  44 check() {
  45   meson test -C build --print-errorlogs
  46 }
  47
  48 package() {
  49   meson install -C build --destdir "$pkgdir"
  50 }
  51
  52 # vim:set sw=2 sts=-1 et: