evolution-data-server/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=evolution-data-server
   5 pkgver=3.44.4
   6 pkgrel=1
   7 pkgdesc="Centralized access to appointments and contacts"
   8 url="https://wiki.gnome.org/Apps/Evolution"
   9 arch=(x86_64)
  10 depends=(gnome-online-accounts nss krb5 libgweather-4 libical db libgdata libphonenumber
  11          libcanberra)
  12 makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git cmake ninja)
  13 provides=(libcamel-1.2.so libebackend-1.2.so libebook-1.2.so libebook-contacts-1.2.so
  14           libecal-2.0.so libedata-book-1.2.so libedata-cal-2.0.so libedataserver-1.2.so
  15           libedataserverui-1.2.so)
  16 license=(GPL)
  17 options=(debug)
  18 _commit=4a526c5363c9c46b200e7fae019c4911c968673f  # tags/3.44.4^0
  19 source=("git+https://gitlab.gnome.org/GNOME/evolution-data-server.git#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/^EVOLUTION_DATA_SERVER_//;s/_/./g;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29 }
  30
  31 build() {
  32   cmake -S $pkgname -B build -G Ninja \
  33     -DCMAKE_INSTALL_PREFIX=/usr \
  34     -DLIBEXEC_INSTALL_DIR=/usr/lib \
  35     -DSYSCONF_INSTALL_DIR=/etc \
  36     -DENABLE_INTROSPECTION=ON \
  37     -DENABLE_VALA_BINDINGS=ON \
  38     -DENABLE_GTK_DOC=ON \
  39     -DWITH_PHONENUMBER=ON \
  40     -DWITH_GWEATHER4=ON
  41   cmake --build build
  42 }
  43
  44 check() {
  45   cd build
  46   ctest --output-on-failure --stop-on-failure
  47 }
  48
  49 package() {
  50   DESTDIR="$pkgdir" cmake --install build
  51 }