feh/trunk/PKGBUILD

   1 # Maintainer: Gaetan Bisson <bisson@archlinux.org>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3 # Contributor: dorphell <dorphell@archlinux.org>
   4 # Contributor: Tom Newsom <Jeepster@gmx.co.uk>
   5
   6 pkgname=feh
   7 pkgver=3.9
   8 pkgrel=1
   9 pkgdesc='Fast and light imlib2-based image viewer'
  10 url='https://feh.finalrewind.org/'
  11 license=('custom:MIT')
  12 arch=('x86_64')
  13 depends=('curl' 'file' 'imlib2' 'libexif' 'libxinerama')
  14 optdepends=('imagemagick: support more file formats'
  15             'jpegexiforient: set exif rotation tag')
  16 makedepends=('libxt')
  17 validpgpkeys=('781BB7071C6BF648EAEB08A1100D5BFB5166E005')
  18 source=("${url}${pkgname}-${pkgver}.tar.bz2"{,.asc})
  19 sha256sums=('8649962c41d2c7ec4cc3f438eb327638a1820ad5a66df6a9995964601ae6bca0'
  20             'SKIP')
  21
  22 build() {
  23         cd "${srcdir}/${pkgname}-${pkgver}"
  24         make PREFIX=/usr \
  25                 exif=1 \
  26                 help=1 \
  27                 inotify=1 \
  28                 magic=1 \
  29                 stat64=1
  30 }
  31
  32 package() {
  33         cd "${srcdir}/${pkgname}-${pkgver}"
  34         make PREFIX=/usr DESTDIR="${pkgdir}" install
  35         install -D -m0644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  36 }