gnome-control-center/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-control-center
   5 pkgver=42.3
   6 pkgrel=1
   7 pkgdesc="GNOME's main interface to configure various aspects of the desktop"
   8 url="https://gitlab.gnome.org/GNOME/gnome-control-center"
   9 license=(GPL2)
  10 arch=(x86_64)
  11 depends=(accountsservice cups-pk-helper gnome-bluetooth-3.0 gnome-desktop-4
  12          gnome-online-accounts gnome-settings-daemon gsettings-desktop-schemas
  13          gtk4 libgtop libnma-gtk4 sound-theme-freedesktop upower libpwquality
  14          gnome-color-manager smbclient libmm-glib libgnomekbd libibus libgudev
  15          bolt udisks2 libadwaita gsound colord-gtk4 gcr libmalcontent)
  16 makedepends=(docbook-xsl modemmanager git python meson)
  17 checkdepends=(python-dbusmock python-gobject xorg-server-xvfb)
  18 optdepends=('system-config-printer: Printer settings'
  19             'gnome-user-share: WebDAV file sharing'
  20             'gnome-remote-desktop: screen sharing'
  21             'rygel: media sharing'
  22             'openssh: remote login'
  23             'power-profiles-daemon: Power profiles support')
  24 groups=(gnome)
  25 options=(debug)
  26 _commit=ff5ab8f715ea02f75cff567ce86830040b0f38cc  # tags/42.3^0
  27 source=("git+https://gitlab.gnome.org/GNOME/gnome-control-center.git#commit=$_commit"
  28         "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
  29 sha256sums=('SKIP'
  30             'SKIP')
  31
  32 pkgver() {
  33   cd $pkgname
  34   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  35 }
  36
  37 prepare() {
  38   cd $pkgname
  39
  40   # Install bare logos into pixmaps, not icons
  41   sed -i "/install_dir/s/'icons'/'pixmaps'/" panels/info-overview/meson.build
  42
  43   git submodule init subprojects/gvc
  44   git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
  45   git submodule update
  46 }
  47
  48
  49 build() {
  50   local meson_options=(
  51     -D documentation=true
  52     -D malcontent=true
  53   )
  54
  55   arch-meson $pkgname build "${meson_options[@]}"
  56   meson compile -C build
  57 }
  58
  59 check() {
  60   meson test -C build --print-errorlogs
  61 }
  62
  63 package() {
  64   meson install -C build --destdir "$pkgdir"
  65   install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
  66 }