gnome-usage/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgname=gnome-usage
   5 pkgver=3.38.1
   6 pkgrel=1
   7 pkgdesc="GNOME application to view information about use of system resources"
   8 url="https://wiki.gnome.org/Apps/Usage"
   9 arch=(x86_64)
  10 license=(GPL3)
  11 depends=(gtk3 libgtop libdazzle tracker3 libhandy xdg-user-dirs)
  12 makedepends=(git meson vala accountsservice gamemode)
  13 optdepends=('accountsservice: show user tags for processes'
  14             'gamemode: show processes requesting game mode')
  15 groups=(gnome-extra)
  16 _commit=4745bb5e8f2a44a35cb410020dcf6e54e73bd6e1  # tags/3.38.1^0
  17 source=("git+https://gitlab.gnome.org/GNOME/gnome-usage.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/^v//;s/-/+/g'
  23 }
  24
  25 build() {
  26   arch-meson $pkgname build
  27   meson compile -C build
  28 }
  29
  30 check() {
  31   meson test -C build --print-errorlogs
  32 }
  33
  34 package() {
  35   meson install -C build --destdir "$pkgdir"
  36 }