libmpeg2/repos/extra-x86_64/PKGBUILD

   1 # Contributor: Sarah Hay <sarah@archlinux.org>
   2 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   3
   4 pkgname=libmpeg2
   5 pkgver=0.5.1
   6 pkgrel=7
   7 pkgdesc="Library for decoding MPEG-1 and MPEG-2 video streams."
   8 arch=('x86_64')
   9 url="http://libmpeg2.sourceforge.net/"
  10 depends=('glibc')
  11 makedepends=('sdl' 'libxv')
  12 optdepends=('sdl: required for mpeg2dec'
  13             'libxv: required for mpeg2dec')
  14 source=(http://libmpeg2.sourceforge.net/files/${pkgname}-${pkgver}.tar.gz
  15         libmpeg2-0.5.1-gcc4.6.patch)
  16 license=('GPL2')
  17 provides=('mpeg2dec')
  18 sha256sums=('dee22e893cb5fc2b2b6ebd60b88478ab8556cb3b93f9a0d7ce8f3b61851871d4'
  19             '763e188eea36ee3cdfb31e7877bbead00676b5766c25175ec6a7eb20884926d1')
  20
  21 prepare() {
  22   cd "${srcdir}/${pkgname}-${pkgver}"
  23   patch -Np1 -i "${srcdir}/libmpeg2-0.5.1-gcc4.6.patch"
  24
  25   sed '/AC_PATH_XTRA/d' -i configure.ac
  26   autoreconf --force --install
  27 }
  28
  29 build() {
  30   cd "${srcdir}/${pkgname}-${pkgver}"
  31   ./configure --prefix=/usr --enable-shared --disable-static
  32   make  OPT_CFLAGS="${CFLAGS}" \
  33         MPEG2DEC_CFLAGS="${CFLAGS}" \
  34         LIBMPEG2_CFLAGS=""
  35 }
  36
  37 package() {
  38   cd "${srcdir}/${pkgname}-${pkgver}"
  39   make DESTDIR="${pkgdir}" install
  40 }