libsmbios/trunk/PKGBUILD

   1 # Maintainer: Jan de Groot <jgc@archlinux.org>
   2 # Contributor: Alessio 'mOLOk' Bolognino <themolok@gmail.com>
   3 # Contributor: daniel g. siegel <dgsiegel@gmail.com>
   4
   5 pkgname=libsmbios
   6 pkgver=2.4.3
   7 pkgrel=5
   8 pkgdesc="A library for providing access to as much BIOS information as possible"
   9 arch=('x86_64')
  10 url="https://github.com/dell/libsmbios"
  11 license=('GPL' 'custom')
  12 depends=('gcc-libs')
  13 makedepends=('libxml2' 'python' 'chrpath' 'doxygen' git cppunit help2man)
  14 optdepends=('python: tools')
  15 _commit=5b72244ca0d09c7f228d571ec2d5d20183486c11  # tags/v2.4.3
  16 source=("git+https://github.com/dell/libsmbios.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/^v//;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26   ./autogen.sh --no-configure
  27 }
  28
  29 build() {
  30   unset MAKEFLAGS
  31   cd $pkgname
  32   mkdir build
  33   cd build
  34   ../configure --prefix=/usr --sbindir=/usr/bin --sysconfdir=/etc --disable-static
  35   make
  36 }
  37
  38 package() {
  39   cd $pkgname/build
  40   make DESTDIR="${pkgdir}" install
  41
  42   chrpath -d "${pkgdir}/usr/bin/smbios-sys-info-lite"
  43   install -m755 -d "${pkgdir}/usr/include"
  44
  45   cp -a ../src/include/* "${pkgdir}/usr/include/"
  46   cp -a out/public-include/* "${pkgdir}/usr/include/"
  47
  48   install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  49   install -m644 ../COPYING-OSL "${pkgdir}/usr/share/licenses/${pkgname}/"
  50 }