meld/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   4 # Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
   5
   6 pkgname=meld
   7 pkgver=3.21.2
   8 pkgrel=1
   9 pkgdesc="Compare files, directories and working copies"
  10 url="https://meldmerge.org/"
  11 license=(GPL)
  12 arch=(any)
  13 depends=(python-gobject python-cairo gtksourceview4 gsettings-desktop-schemas
  14          dconf)
  15 makedepends=(meson yelp-tools git)
  16 _commit=29f751b10d5eb661878f416a0dc3b424442b0521  # tags/3.21.2^0
  17 source=("git+https://gitlab.gnome.org/GNOME/meld.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd meld
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd meld
  27 }
  28
  29 build() {
  30   arch-meson meld build
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package() {
  39   meson install -C build --destdir "$pkgdir"
  40   python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  41   python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
  42 }