opencolorio/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Contributor: Dumitru Ursu <dima@ceata.org>
   3
   4 pkgname=opencolorio
   5 pkgver=2.1.2
   6 pkgrel=1
   7 pkgdesc="A color management framework for visual effects and animation"
   8 arch=('x86_64')
   9 url="https://opencolorio.org"
  10 license=('BSD')
  11 depends=('freeglut' 'glew' 'lcms2' 'tinyxml' 'yaml-cpp' 'imath' 'pystring')
  12 makedepends=('cmake' 'python' 'pybind11' 'ninja')
  13 optdepends=('python: python bindings')
  14 source=($pkgname-$pkgver.tar.gz::https://github.com/AcademySoftwareFoundation/OpenColorIO/archive/v$pkgver.tar.gz
  15         https://github.com/AcademySoftwareFoundation/OpenColorIO/commit/4fa94918c2cf572dcaf61ca07016f3b5c231c14c.patch)
  16 sha512sums=('594e808fb1c175d5b14eb540be0dfb6f41cd37b5bf7df8c2d24d44dfe4986643ea68e52d0282eb3b25283489789001a57a201de1eecc1560fc9461780c7da353'
  17             'baffedf7d81c67c9a14f5977379a86eeed3d9891069ad810e4303994369b500e78c43e4c0fcbe5bd7f7ba16163c16b6796884f4250ff6200a162ed29d60780fb')
  18
  19 prepare() {
  20   cd OpenColorIO-$pkgver
  21
  22   # We don't care about the failures of this patch in this current release
  23   patch -Np1 -i "$srcdir"/4fa94918c2cf572dcaf61ca07016f3b5c231c14c.patch || true
  24 }
  25
  26 build() {
  27   cd OpenColorIO-$pkgver
  28
  29   CXXFLAGS+=" -ffat-lto-objects"
  30   cmake \
  31     -GNinja \
  32     -Bbuild \
  33     -DCMAKE_INSTALL_PREFIX=/usr \
  34     -DCMAKE_INSTALL_LIBDIR=lib
  35   ninja -C build
  36 }
  37
  38 package() {
  39   cd OpenColorIO-$pkgver
  40
  41   DESTDIR="$pkgdir" ninja -C build install
  42   install -Dm644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
  43 }
  44
  45 # vim:set ts=2 sw=2 et: