pygobject/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=pygobject
   5 pkgname=(python-gobject)
   6 pkgver=3.42.2
   7 pkgrel=1
   8 pkgdesc="Python Bindings for GLib/GObject/GIO/GTK+"
   9 url="https://wiki.gnome.org/Projects/PyGObject"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(gobject-introspection-runtime python)
  13 makedepends=(python-cairo gobject-introspection git meson)
  14 checkdepends=(python-pytest gtk3 xorg-server-xvfb)
  15 optdepends=('cairo: Cairo bindings')
  16 provides=("pygobject-devel=$pkgver")
  17 conflicts=(pygobject-devel)
  18 replaces=('pygobject-devel<=3.36.1-1')
  19 options=(debug)
  20 _commit=f9c363a0c2fea08b140dbb9c9f072cbeb0cf1f10  # tags/3.42.2^0
  21 source=("git+https://gitlab.gnome.org/GNOME/pygobject.git#commit=$_commit")
  22 sha256sums=('SKIP')
  23
  24 pkgver() {
  25   cd pygobject
  26   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  27 }
  28
  29 prepare() {
  30   cd pygobject
  31 }
  32
  33 build() {
  34   arch-meson pygobject build
  35   meson compile -C build
  36 }
  37
  38 check() {
  39   xvfb-run -s '-nolisten local' meson test -C build --print-errorlogs
  40 }
  41
  42 package_python-gobject() {
  43   meson install -C build --destdir "$pkgdir"
  44   python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  45   python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
  46 }
  47
  48 # vim:set sw=2 et: