qt6-httpserver/kde-unstable/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3
   4 pkgname=qt6-httpserver
   5 _qtver=6.4.0-beta2
   6 pkgver=${_qtver/-/}
   7 pkgrel=1
   8 arch=(x86_64)
   9 url='https://www.qt.io'
  10 license=(GPL3 LGPL3 FDL custom)
  11 pkgdesc='Qt HTTP Server'
  12 depends=(qt6-websockets)
  13 makedepends=(cmake ninja)
  14 optdepends=('qt6-declarative: QML bindings')
  15 groups=(qt6)
  16 options=(debug)
  17 _pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
  18 source=(https://download.qt.io/development_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
  19 sha256sums=('8aca7185902d75aa06b0fac193888b357a59b9b2fe34c02f90bc115029a7b2f6')
  20
  21 build() {
  22   cmake -B build -S $_pkgfn -G Ninja \
  23     -DCMAKE_MESSAGE_LOG_LEVEL=STATUS
  24   cmake --build build
  25 }
  26
  27 package() {
  28   DESTDIR="$pkgdir" cmake --install build
  29
  30   install -d "$pkgdir"/usr/share/licenses
  31   ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
  32 }