tracker-miners/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=tracker-miners
   4 pkgver=2.3.5+r3+gd9d61d87f
   5 pkgrel=1
   6 epoch=1
   7 pkgdesc="Collection of data extractors for Tracker/Nepomuk"
   8 url="https://wiki.gnome.org/Projects/Tracker"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(tracker gst-plugins-base-libs exempi flac libexif libcue libgrss libgsf
  12          libgxps libiptcdata libosinfo libvorbis poppler-glib totem-plparser
  13          giflib libgexiv2 gupnp-dlna upower libseccomp)
  14 makedepends=(intltool git meson vala)
  15 checkdepends=(python-gobject gst-plugins-good gst-plugins-base gst-libav)
  16 options=(debug)
  17 _commit=d9d61d87f2474d1349fac977fa6de07ad6ab50b7  # tracker-miners-2.3
  18 source=("git+https://gitlab.gnome.org/GNOME/tracker-miners.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd tracker-miners
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd tracker-miners
  28 }
  29
  30 build() {
  31   arch-meson tracker-miners build
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   # Intermittent test failures: https://gitlab.gnome.org/GNOME/tracker-miners/-/issues/79
  37   dbus-run-session meson test -C build --print-errorlogs -t 3 || :
  38 }
  39
  40 package() {
  41   depends+=(libtracker-{miner,sparql}-2.0.so)
  42
  43   meson install -C build --destdir "$pkgdir"
  44 }
  45
  46 # vim:set sw=2 et: