xdg-desktop-portal/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Patrick Griffis <tingping@tingping.se>
   4
   5 pkgname=xdg-desktop-portal
   6 pkgver=1.14.6
   7 pkgrel=1
   8 pkgdesc="Desktop integration portals for sandboxed apps"
   9 url="https://github.com/flatpak/xdg-desktop-portal"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(glib2 pipewire fuse3 geoclue2 rtkit systemd)
  13 makedepends=(python xmlto docbook-xsl git flatpak libportal)
  14 options=(debug)
  15 _commit=bd1eab9361832f320a83ea3b2a98c8894376fc22  # tags/1.14.6
  16 source=("git+https://github.com/flatpak/xdg-desktop-portal#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26   NOCONFIGURE=1 ./autogen.sh
  27 }
  28
  29 build() {
  30   cd $pkgname
  31   ./configure --prefix=/usr --libexecdir=/usr/lib
  32   make
  33 }
  34
  35 package() {
  36   depends+=(xdg-desktop-portal-impl)
  37
  38   cd $pkgname
  39   make DESTDIR="$pkgdir" install
  40 }