xorg-font-util/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=xorg-font-util
   5 pkgver=1.3.3
   6 pkgrel=1
   7 pkgdesc='X.Org font utilities'
   8 url='https://xorg.freedesktop.org/'
   9 arch=('x86_64')
  10 license=('custom')
  11 makedepends=('xorg-util-macros')
  12 depends=('glibc')
  13 source=("${url}"/releases/individual/font/font-util-${pkgver}.tar.xz{,.sig})
  14 sha512sums=('5e1cb8af44fe0bea72b1a6a4e455f50ca49b7531c2f4b605800c0b2b7578b9826ccf17fa195c505ab1d6339fd4ad697c01ba3b9777616f354ab62b23434d47c9'
  15             'SKIP')
  16 validpgpkeys=('4A193C06D35E7C670FA4EF0BA2FB9E081F2D130E') # Alan Coopersmith <alan.coopersmith@oracle.com>
  17 replaces=('font-util')
  18 provides=('font-util')
  19 conflicts=('font-util')
  20 groups=('xorg-fonts' 'xorg')
  21
  22 build() {
  23   cd font-util-${pkgver}
  24   ./configure \
  25     --prefix=/usr \
  26     --mandir=/usr/share/man \
  27     --with-mapdir=/usr/share/fonts/util \
  28     --with-fontrootdir=/usr/share/fonts
  29   make
  30 }
  31
  32 package() {
  33   cd font-util-${pkgver}
  34   make DESTDIR="${pkgdir}" install
  35   install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  36 }