gcr/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=gcr
   5 pkgver=3.41.0
   6 pkgrel=2
   7 pkgdesc="A library for bits of crypto UI and parsing"
   8 url="https://gitlab.gnome.org/GNOME/gcr"
   9 arch=(x86_64)
  10 license=(GPL2)
  11 depends=(gtk3 libgcrypt p11-kit openssh libsecret)
  12 makedepends=(gobject-introspection vala libxslt git gtk-doc meson)
  13 provides=(libgck-1.so libgcr-{base,ui}-3.so)
  14 backup=(etc/security/limits.d/10-gcr.conf)
  15 install=gcr.install
  16 options=(debug)
  17 _commit=f5026a8c9c7d78372b3efeca3412b0e40011ce11  # tags/3.41.0^0
  18 source=("git+https://gitlab.gnome.org/GNOME/gcr.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd gcr
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd gcr
  28
  29   # Fix build
  30   git cherry-pick -n b3ca1d02bb0148ca787ac4aead164d7c8ce2c4d8
  31 }
  32
  33 build() {
  34   arch-meson gcr build
  35   meson compile -C build
  36 }
  37
  38 check() {
  39   # Secure memory tests fail
  40   dbus-run-session meson test -C build --print-errorlogs || :
  41 }
  42
  43 package() {
  44   meson install -C build --destdir "$pkgdir"
  45
  46   # gcr wants to lock some memory to prevent swapping out private keys
  47   # https://bugs.archlinux.org/task/32616
  48   # https://bugzilla.gnome.org/show_bug.cgi?id=688161
  49   install -Dm644 /dev/stdin "$pkgdir/etc/security/limits.d/10-gcr.conf" <<END
  50 @users - memlock 1024
  51 END
  52 }
  53
  54 # vim:set ts=2 sw=2 et: