libgnome-games-support-2/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=libgnome-games-support-2
   4 pkgver=2.0.0
   5 pkgrel=1
   6 pkgdesc="Code shared between GNOME games"
   7 url="https://gitlab.gnome.org/GNOME/libgnome-games-support"
   8 arch=(x86_64)
   9 license=(GPL3 LGPL3)
  10 depends=(libgee gtk4)
  11 makedepends=(vala git meson)
  12 provides=("libgnome-games-support-${pkgver%%.*}.so")
  13 _commit=75ed95f923d77705d5cb5eea14625a655a3225c8  # tags/2.0.0^0
  14 source=("git+https://gitlab.gnome.org/GNOME/libgnome-games-support.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd libgnome-games-support
  19   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd libgnome-games-support
  24 }
  25
  26 build() {
  27   arch-meson libgnome-games-support build
  28   meson compile -C build
  29 }
  30
  31 check() {
  32   meson test -C build --print-errorlogs
  33 }
  34
  35 package() {
  36   meson install -C build --destdir "$pkgdir"
  37 }