libhandy/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgbase=libhandy
   5 pkgname=(libhandy libhandy-docs)
   6 pkgver=1.8.2
   7 pkgrel=1
   8 pkgdesc="Library full of GTK+ widgets for mobile phones"
   9 url="https://gitlab.gnome.org/GNOME/libhandy"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(
  13   glib2
  14   gtk3
  15 )
  16 makedepends=(
  17   gi-docgen
  18   git
  19   glade
  20   gobject-introspection
  21   meson
  22   vala
  23 )
  24 checkdepends=(xorg-server-xvfb)
  25 _commit=48ae7ec0f7f9ee5f666da38b0e39e66874957166  # tags/1.8.2^0
  26 source=("git+https://gitlab.gnome.org/GNOME/libhandy.git#commit=$_commit")
  27 sha256sums=('SKIP')
  28
  29 pkgver() {
  30   cd libhandy
  31   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  32 }
  33
  34 prepare() {
  35   cd libhandy
  36 }
  37
  38 build() {
  39   arch-meson libhandy build -D gtk_doc=true
  40   meson compile -C build
  41 }
  42
  43 check() {
  44   dbus-run-session xvfb-run -s '-nolisten local' \
  45     meson test -C build --print-errorlogs
  46 }
  47
  48 package_libhandy() {
  49   provides=(libhandy-1.so)
  50
  51   meson install -C build --destdir "$pkgdir"
  52
  53   mkdir -p doc/usr/share
  54   mv {"$pkgdir",doc}/usr/share/doc
  55 }
  56
  57 package_libhandy-docs() {
  58   pkgdesc+=" (documentation)"
  59   depends=()
  60
  61   mv doc/* "$pkgdir"
  62 }
  63
  64 # vim:set sw=2 sts=-1 et: