pangox-compat/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
   2
   3 pkgname=pangox-compat
   4 pkgver=0.0.2+2+gedb9e09
   5 pkgrel=3
   6 pkgdesc="X Window System font support for Pango"
   7 arch=('x86_64')
   8 license=('LGPL')
   9 depends=('pango')
  10 makedepends=(git)
  11 _commit=edb9e0904d04d1da02bba7b78601a2aba05aaa47  # master
  12 source=("git+https://gitlab.gnome.org/Archive/pangox-compat#commit=$_commit"
  13         0001-Re-add-pango_x_get_shaper_map-it-is-still-used-in-th.patch)
  14 url="http://www.pango.org/"
  15 sha256sums=('SKIP'
  16             'd5aad903439ede05b866c9a2962f293bec4897f07d5a7b07ebc5aa99eeb27e48')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25   patch -Np1 -i ../0001-Re-add-pango_x_get_shaper_map-it-is-still-used-in-th.patch
  26   NOCONFIGURE=1 ./autogen.sh
  27 }
  28
  29 build() {
  30   cd $pkgname
  31
  32   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  33     --disable-static
  34   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  35   make
  36 }
  37
  38 package() {
  39   cd $pkgname
  40   make -j1 DESTDIR="${pkgdir}" install
  41 }