qt6-declarative/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4
   5 pkgname=qt6-declarative
   6 _qtver=6.5.0
   7 pkgver=${_qtver/-/}
   8 pkgrel=2
   9 arch=(x86_64)
  10 url='https://www.qt.io'
  11 license=(GPL3 LGPL3 FDL custom)
  12 pkgdesc='Classes for QML and JavaScript languages'
  13 depends=(qt6-base)
  14 makedepends=(cmake ninja python at-spi2-core qt6-shadertools qt6-languageserver qt6-tools)
  15 optdepends=('qt6-languageserver: for qmlls')
  16 conflicts=(qt6-quickcontrols2)
  17 provides=(qt6-quickcontrols2)
  18 replaces=(qt6-quickcontrols2)
  19 groups=(qt6)
  20 _pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
  21 source=(https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
  22 sha256sums=('f7d631cd8ebc1491dad0f30f1b5326ae812bee4ad706e61157816a82bf588c97')
  23
  24 build() {
  25   export CXXFLAGS+=" -ffat-lto-objects"
  26   cmake -B build -S $_pkgfn -G Ninja \
  27     -DINSTALL_PUBLICBINDIR=usr/bin \
  28     -DCMAKE_MESSAGE_LOG_LEVEL=STATUS
  29   cmake --build build
  30 }
  31
  32 package() {
  33   DESTDIR="$pkgdir" cmake --install build
  34
  35 # Install symlinks for user-facing tools
  36   cd "$pkgdir"
  37   mkdir usr/bin
  38   while read _line; do
  39     ln -s $_line
  40   done < "$srcdir"/build/user_facing_tool_links.txt
  41
  42   install -d "$pkgdir"/usr/share/licenses
  43   ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
  44 }