pcre/trunk/PKGBUILD

   1 # Maintainer: Sébastien "Seblu" Luttringer
   2 # Contributor: Allan McRae <allan@archlinux.org>
   3 # Contributor: Eric Belanger <eric@archlinux.org>
   4 # Contributor: John Proctor <jproctor@prium.net>
   5
   6 pkgname=pcre
   7 pkgver=8.45
   8 pkgrel=3
   9 pkgdesc='A library that implements Perl 5-style regular expressions'
  10 arch=('x86_64')
  11 url='https://www.pcre.org/'
  12 license=('BSD')
  13 depends=('gcc-libs' 'readline' 'zlib' 'bzip2' 'bash')
  14 provides=(libpcre{,16,32,posix,cpp}.so)
  15 source=("https://sourceforge.net/projects/pcre/files/$pkgname/$pkgver/$pkgname-$pkgver.tar.bz2"{,.sig})
  16 sha512sums=('91bff52eed4a2dfc3f3bfdc9c672b88e7e2ffcf3c4b121540af8a4ae8c1ce05178430aa6b8000658b9bb7b4252239357250890e20ceb84b79cdfcde05154061a'
  17             'SKIP')
  18 validpgpkeys=('45F68D54BBE23FB3039B46E59766E084FB0F43D8')  # Philip Hazel <ph10@hermes.cam.ac.uk>
  19
  20 build() {
  21   cd $pkgname-$pkgver
  22   ./configure \
  23     --prefix=/usr \
  24     --enable-unicode-properties \
  25     --enable-pcre16 \
  26     --enable-pcre32 \
  27     --enable-jit \
  28     --enable-pcregrep-libz \
  29     --enable-pcregrep-libbz2 \
  30     --enable-pcretest-libreadline
  31   make
  32 }
  33
  34 check() {
  35   cd $pkgname-$pkgver
  36   make -j1 check
  37 }
  38
  39 package() {
  40   cd $pkgname-$pkgver
  41   make DESTDIR="$pkgdir" install
  42
  43   install -Dm644 LICENCE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  44 }
  45
  46 # vim:set sw=2 sts=-1 et: