gnome-color-manager/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-color-manager
   4 pkgver=3.36.0+r42+g90481514
   5 pkgrel=1
   6 pkgdesc="GNOME Color Profile Tools"
   7 url="https://gitlab.gnome.org/GNOME/gnome-color-manager"
   8 arch=(x86_64)
   9 license=(GPL2)
  10 depends=(glib2 gtk3 colord lcms2)
  11 makedepends=(yelp-tools git appstream-glib meson docbook-utils docbook-sgml
  12              perl-sgmls)
  13 checkdepends=(xorg-server-xvfb)
  14 groups=(gnome)
  15 options=(debug)
  16 _commit=904815149a2ad20d89d34639bb6ab442db15ea1f  # master
  17 source=("git+https://gitlab.gnome.org/GNOME/gnome-color-manager.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/^GNOME_COLOR_MANAGER_//;s/_/./g;s/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27 }
  28
  29 build() {
  30   arch-meson $pkgname build
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   dbus-run-session xvfb-run -s '-nolisten local' \
  36     meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41 }
  42
  43 # vim:set sw=2 sts=-1 et: