libspiro/trunk/PKGBUILD

   1 # Maintainer: Gaetan Bisson <bisson@archlinux.org>
   2 # Contributor: Rémy Oudompheng <oudomphe@clipper.ens.fr>
   3
   4 pkgname=libspiro
   5 epoch=1
   6 pkgver=20221101
   7 pkgrel=1
   8 pkgdesc='Simplifies the drawing of beautiful curves'
   9 url='https://github.com/fontforge/libspiro'
  10 license=('GPL')
  11 arch=('x86_64')
  12 source=("https://github.com/fontforge/libspiro/releases/download/${pkgver}/libspiro-dist-${pkgver}.tar.gz")
  13 depends=(glibc)
  14 sha256sums=('5984fb5af3e4e1f927f3a74850b705a711fb86284802a5e6170b09786440e8be')
  15
  16 prepare() {
  17   cd ${pkgname}-${pkgver}
  18   autoreconf -i
  19   automake --foreign -Wall
  20 }
  21
  22 build() {
  23   cd ${pkgname}-${pkgver}
  24   ./configure --prefix=/usr
  25   make
  26 }
  27
  28 check() {
  29   cd ${pkgname}-${pkgver}
  30   make check
  31 }
  32
  33 package() {
  34   cd ${pkgname}-${pkgver}
  35   make DESTDIR="${pkgdir}" install
  36   install -Dm644 libspiro.pc "${pkgdir}"/usr/lib/pkgconfig/libspiro.pc
  37 }