yelp/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=yelp
   5 pkgver=42.2
   6 pkgrel=1
   7 pkgdesc="Get help with GNOME"
   8 url="https://wiki.gnome.org/Apps/Yelp"
   9 license=(GPL)
  10 arch=(x86_64)
  11 depends=(webkit2gtk-4.1 yelp-xsl libxslt xz bzip2 libhandy)
  12 makedepends=(itstool autoconf-archive git appstream-glib)
  13 provides=(libyelp.so)
  14 groups=(gnome)
  15 _commit=9fd1a84e1eae23db21939ff76c7e96d5422d3b1a  # tags/42.2^0
  16 source=("git+https://gitlab.gnome.org/GNOME/yelp.git#commit=$_commit"
  17         no-gtk-doc.diff)
  18 sha256sums=('SKIP'
  19             '795b8b6ee7cbbf6ccdbeba70ac8335becaaa6a44abe82f90c1c95d8113e4bf28')
  20
  21 pkgver() {
  22   cd yelp
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd yelp
  28
  29   # Remove vestiges of docs build to allow building without gtk-doc
  30   git apply -3 ../no-gtk-doc.diff
  31
  32   NOCONFIGURE=1 ./autogen.sh
  33 }
  34
  35 build() {
  36   cd yelp
  37   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  38     --disable-static --enable-compile-warnings=minimum
  39   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  40   make
  41 }
  42
  43 package() {
  44   cd yelp
  45   make DESTDIR="$pkgdir" install
  46 }