fixesproto/trunk/PKGBUILD

   1 #Maintainer: Jan de Groot <jgc@archlinux.org>
   2
   3 pkgname=fixesproto
   4 pkgver=5.0+9+g4292ec1
   5 pkgrel=1
   6 pkgdesc="X11 Fixes extension wire protocol"
   7 arch=('any')
   8 url="https://xorg.freedesktop.org/"
   9 license=('custom')
  10 depends=('xproto' 'xextproto')
  11 makedepends=('xorg-util-macros' git)
  12 _commit=4292ec1c63180c5f4e7c0e606fa68c51913f172b  # master
  13 source=("git+https://anongit.freedesktop.org/git/xorg/proto/fixesproto#commit=$_commit")
  14 sha1sums=('SKIP')
  15
  16 pkgver() {
  17   cd $pkgname
  18   git describe --tags | sed 's/^fixesproto-//;s/-/+/g'
  19 }
  20
  21 prepare() {
  22   cd $pkgname
  23   NOCONFIGURE=1 ./autogen.sh
  24 }
  25
  26 build() {
  27   cd "${srcdir}/$pkgname"
  28   ./configure --prefix=/usr
  29   make
  30 }
  31
  32 package() {
  33   cd "${srcdir}/$pkgname"
  34   make DESTDIR="${pkgdir}" install
  35   install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  36 }