gnome-books/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-books
   4 pkgver=40.0
   5 pkgrel=1
   6 pkgdesc="Access and organize your e-books on GNOME"
   7 url="https://wiki.gnome.org/Apps/Books"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(evince gjs gtk3 gnome-desktop tracker3-miners webkit2gtk libgepub
  11          gnome-epub-thumbnailer)
  12 makedepends=(gobject-introspection git meson yelp-tools)
  13 groups=(gnome-extra)
  14 _commit=e5a6646a5586f36e0ee3167a77237b4c7eaff8e0  # tags/40.0^0
  15 source=("git+https://gitlab.gnome.org/GNOME/gnome-books.git#commit=$_commit"
  16         "git+https://gitlab.gnome.org/GNOME/libgd.git")
  17 sha256sums=('SKIP'
  18             'SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27
  28   git submodule init
  29   git submodule set-url subprojects/libgd "$srcdir/libgd"
  30   git -c protocol.file.allow=always submodule update
  31 }
  32
  33
  34 build() {
  35   arch-meson $pkgname build
  36   meson compile -C build
  37 }
  38
  39 check() {
  40   meson test -C build --print-errorlogs
  41 }
  42
  43 package() {
  44   meson install -C build --destdir="$pkgdir"
  45 }
  46
  47 # vim:set sw=2 sts=-1 et: