json-glib/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=json-glib
   5 pkgname=(json-glib json-glib-docs)
   6 pkgver=1.6.6
   7 pkgrel=2
   8 pkgdesc="JSON library built on GLib"
   9 url="https://wiki.gnome.org/Projects/JsonGlib"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(glib2)
  13 makedepends=(gobject-introspection git meson gi-docgen docbook-xsl)
  14 _commit=3cf2b53667a73376c852e08dcadd197a5f8325b9  # tags/1.6.6^0
  15 source=("git+https://gitlab.gnome.org/GNOME/json-glib.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd json-glib
  20   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd json-glib
  25 }
  26
  27 build() {
  28   arch-meson json-glib build -D man=true
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   meson test -C build --print-errorlogs
  34 }
  35
  36 package_json-glib() {
  37   depends+=(libg{lib,object,io}-2.0.so)
  38   provides+=(libjson-glib-1.0.so)
  39
  40   meson install -C build --destdir "$pkgdir"
  41
  42   mkdir -p doc/usr/share
  43   mv {"$pkgdir",doc}/usr/share/doc
  44
  45   rm -r "$pkgdir"/usr/{lib,share}/installed-tests
  46 }
  47
  48 package_json-glib-docs() {
  49   pkgdesc+=" (documentation)"
  50   depends=()
  51
  52   mv doc/* "$pkgdir"
  53 }
  54
  55 # vim:set sw=2 et: