libpsl/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Darshit Shah <darnir@gmail.com>
   3
   4 pkgname=libpsl
   5 pkgver=0.21.2
   6 pkgrel=1
   7 pkgdesc='Public Suffix List library'
   8 url='https://github.com/rockdaboot/libpsl'
   9 arch=('x86_64')
  10 license=('MIT')
  11 depends=('libidn2' 'libunistring')
  12 makedepends=('libxslt' 'python' 'publicsuffix-list' 'gtk-doc')
  13 provides=('libpsl.so')
  14 source=(https://github.com/rockdaboot/libpsl/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.gz)
  15 sha512sums=('f1df72220bf4391d4701007100b0df66c833a2cbcb7481c9d13f0b9e0cad3b66d2d15d4b976e5bad60d2ad1540355112fa1acb07aa925c241d2d7cd20681c71d')
  16 b2sums=('b50f805bb467dc3284bc91645a37a2208098ad809d3771c74ef13c3b8f6029a07ad80a56702c7e3d1a1125d272403c85dd97b64a28465b9ff2d095eaf94b9a4d')
  17
  18 prepare() {
  19   cd ${pkgname}-${pkgver}
  20   rm -frv list
  21   autoreconf -fiv
  22 }
  23
  24 build() {
  25   cd ${pkgname}-${pkgver}
  26   ./configure \
  27     --prefix=/usr \
  28     --disable-static \
  29     --disable-dependency-tracking \
  30     --enable-man \
  31     --enable-gtk-doc \
  32     --enable-{builtin,runtime}=libidn2 \
  33     --with-psl-file=/usr/share/publicsuffix/effective_tld_names.dat \
  34     --with-psl-testfile=/usr/share/publicsuffix/test_psl.txt
  35   LC_CTYPE=en_US.UTF-8 make
  36 }
  37
  38 check() {
  39   cd ${pkgname}-${pkgver}
  40   make check
  41 }
  42
  43 package() {
  44   depends+=('libidn2.so' 'libunistring.so')
  45
  46   cd ${pkgname}-${pkgver}
  47   make DESTDIR="${pkgdir}" install
  48   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  49 }
  50
  51 # vim: ts=2 sw=2 et: