libvoikko/trunk/PKGBUILD

   1 # Maintainer:
   2 # Contributor:  Jesse Jaara     <gmail.com: jesse.jaara>
   3 # Contributor:  Jussi Timperi   <gmail.com: jussi.timperi>
   4
   5 pkgname=libvoikko
   6 pkgver=4.3.2
   7 pkgrel=2
   8 pkgdesc="A spelling and grammar checker, hyphenator and collection of related linguistic data for Finnish language"
   9 arch=(x86_64)
  10 url="http://voikko.sourceforge.net"
  11 license=(GPL2)
  12 depends=(gcc-libs)
  13 makedepends=(python)
  14 source=(https://www.puimula.org/voikko-sources/libvoikko/$pkgname-$pkgver.tar.gz{,.asc})
  15 sha512sums=('d510a9344501f86b2f644c1237faf8709f02b5d17bca76f7934c8422495aeee307f12c60dde47df15a39c24c3311253d3dea2d0648050fc3a056a22497de695c'
  16             'SKIP')
  17 validpgpkeys=('AC5D65F10C8596D7E2DAE2633D309B604AE3942E') # Harri Pitkänen <hatapitk@iki.fi>
  18
  19 build() {
  20   cd $pkgname-$pkgver
  21
  22 # Workaround encoding error
  23   export LANG=en_US.UTF-8
  24   ./configure --prefix=/usr --enable-hfst=false --with-dictionary-path=/usr/share/voikko
  25   make
  26 }
  27
  28 package() {
  29   cd $pkgname-$pkgver
  30   local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
  31
  32   make DESTDIR="$pkgdir" install
  33   mkdir -p "$pkgdir"/usr/lib/"python${python_version}"/site-packages
  34   cp python/libvoikko.py "$pkgdir"/usr/lib/"python${python_version}"/site-packages/libvoikko.py
  35 }