links/trunk/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2 # Contributor: Eric Bélanger <eric@archlinux.org>
   3
   4 pkgname=links
   5 pkgver=2.29
   6 pkgrel=1
   7 pkgdesc='A text WWW browser, similar to Lynx'
   8 arch=('x86_64')
   9 url='http://links.twibright.com/'
  10 license=('GPL')
  11 depends=('brotli' 'libbrotlidec.so' 'bzip2' 'libbz2.so' 'gpm' 'libgpm.so'
  12          'libevent' 'openssl' 'xz' 'zstd' 'libzstd.so')
  13 makedepends=('libtiff' 'libpng' 'libxt' 'librsvg')
  14 optdepends=('libx11: for using xlinks'
  15             'libtiff: for using xlinks'
  16             'libpng: for using xlinks'
  17             'librsvg: for using xlinks')
  18 source=("http://links.twibright.com/download/${pkgname}-${pkgver}.tar.bz2"
  19         'links.desktop')
  20 sha256sums=('22aa96c0b38e1a6f8f7ed9d7a4167a47fc37246097759ef6059ecf8f9ead7998'
  21             'f96bf2638e9c309bfdb857bd62a732b980231b3a683cd585ec872b249c2c1b19')
  22
  23 configure_options=(
  24   --prefix=/usr
  25   --mandir=/usr/share/man
  26   --disable-javascript
  27 )
  28
  29 prepare() {
  30   cd ${pkgname}-${pkgver}
  31   sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" configure
  32 }
  33
  34 build() {
  35   cd ${pkgname}-${pkgver}
  36   (cd intl; ./gen-intl; ./synclang)
  37   ./configure \
  38     "${configure_options[@]}" \
  39     --enable-graphics \
  40     --with-x \
  41     --with-fb
  42   make
  43   mv links xlinks
  44
  45   ./configure \
  46     "${configure_options[@]}" \
  47     --disable-graphics \
  48     --without-x \
  49     --without-fb
  50   make
  51 }
  52
  53 package() {
  54   cd ${pkgname}-${pkgver}
  55   make DESTDIR="${pkgdir}" install
  56
  57   install -D -m0755 xlinks "${pkgdir}/usr/bin/xlinks"
  58   ln -s links.1.gz "${pkgdir}/usr/share/man/man1/xlinks.1.gz"
  59
  60   install -D -m0644 "${srcdir}/links.desktop" "${pkgdir}/usr/share/applications/links.desktop"
  61   install -d "${pkgdir}/usr/share/pixmaps"
  62   install -m0644 links_16x16_1.xpm links_16x16_2.xpm links_32x32.xpm links-48x48.xpm "${pkgdir}/usr/share/pixmaps/"
  63
  64   install -d "${pkgdir}/usr/share/doc/links/calibration"
  65   install -m0644 doc/links_cal/* "${pkgdir}/usr/share/doc/links/calibration/"
  66 }