mlt/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Fabian Schoelzel <myfirstname.mylastname@googlemail.com>
   4 # Contributor: funkyou <spamopfer@nickname.berlin.de>
   5 # Contributor: tardo <tardo@nagi-fanboi.net>
   6 # Contributor: Stefan Husmann <stefan-husmann@t-online.de>
   7 # Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>
   8
   9 pkgname=mlt
  10 pkgver=7.16.0
  11 pkgrel=1
  12 pkgdesc='An open source multimedia framework'
  13 arch=(x86_64)
  14 url='https://www.mltframework.org'
  15 license=(GPL)
  16 depends=(libebur128)
  17 optdepends=('sdl_image: SDL1 plugin'
  18             'sdl2: SDL2 plugin'
  19             'libsamplerate: libavresample plugin'
  20             'sox: SOX (Audio Swiss Army Knife) plugin'
  21             'ffmpeg: ffmpeg plugin'
  22             'vid.stab: video stabilize plugin'
  23             'qt5-svg: Qt5 plugins'
  24             'qt6-svg: Qt6 plugin' 'qt6-5compat: Qt6 plugin'
  25             'jack: JACK sound output plugin'
  26             'ladspa: LADSPA plugins'
  27             'libexif: auto rotate plugin'
  28             'frei0r-plugins: for additional effects'
  29             'movit: opengl plugin'
  30             'opencv: openCV plugin'
  31             'rubberband: audio pitch plugin'
  32             'gdk-pixbuf2: gdk plugin'
  33             'pango: gdk plugin'
  34             'rtaudio: rtaudio plugin'
  35             'python: python bindings')
  36 makedepends=(cmake ladspa frei0r-plugins libdv sdl_image libsamplerate sox ffmpeg vid.stab qt5-svg qt6-svg qt6-5compat
  37              jack libexif python swig movit eigen opencv rubberband gdk-pixbuf2 pango rtaudio imagemagick)
  38 source=(https://github.com/mltframework/mlt/releases/download/v$pkgver/mlt-$pkgver.tar.gz)
  39 sha256sums=('c0975e06403d3df22be7d4b5d96d0608e0d16470299360d0a0ee5f41ba2b7a96')
  40
  41 build() {
  42   cmake -B build -S $pkgname-$pkgver \
  43     -DCMAKE_INSTALL_PREFIX=/usr \
  44     -DMOD_OPENCV=ON \
  45     -DMOD_GLAXNIMATE=ON \
  46     -DMOD_QT6=ON \
  47     -DSWIG_PYTHON=ON
  48   cmake --build build
  49 }
  50
  51 package() {
  52   DESTDIR="$pkgdir" cmake --install build
  53 }