perl-event-execflow/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@gmail.com>
   2 # Contributor: tobias <tobias@archlinux.org>
   3 # Contributor: Tobias Kieslich <tobias@justdreams.de>
   4
   5 pkgname=perl-event-execflow
   6 _realname=Event-ExecFlow
   7 pkgver=0.64
   8 pkgrel=8
   9 pkgdesc="Framework for perl-events"
  10 arch=('any')
  11 license=('PerlArtistic')
  12 url="https://www.exit1.org/${_realname}/"
  13 depends=('perl-anyevent' 'perl-libintl-perl' 'perl>=5.10.0')
  14 options=('!emptydirs')
  15 source=(https://search.cpan.org/CPAN/authors/id/J/JR/JRED/${_realname}-${pkgver}.tar.gz)
  16 sha256sums=('c4e9f4e764216efa5e2b9efe90a6582b81cb8aed4c138b4bad747ed3bd16b7bf')
  17
  18 build() {
  19   cd "${srcdir}/${_realname}-${pkgver}"
  20   # install module in vendor directories.
  21   PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  22   make
  23 }
  24
  25 check() {
  26   cd "${srcdir}/${_realname}-${pkgver}"
  27   make test
  28 }
  29
  30 package() {
  31   cd "${srcdir}/${_realname}-${pkgver}"
  32   make install DESTDIR="${pkgdir}/"
  33
  34   # remove perllocal.pod and .packlist
  35   find "${pkgdir}" -name perllocal.pod -delete
  36   find "${pkgdir}" -name .packlist -delete
  37 }