python-evdev/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=python-evdev
   4 pkgver=1.6.1
   5 pkgrel=2
   6 pkgdesc="Python bindings for the Linux input subsystem"
   7 url="https://python-evdev.readthedocs.io/en/latest/"
   8 arch=(x86_64)
   9 license=(BSD)
  10 depends=(python)
  11 makedepends=(python-setuptools python-build python-installer python-wheel git)
  12 _commit=2dd6ce6364bb67eedb209f6aa0bace0c18a3a40a  # tags/v1.6.1^0
  13 source=("git+https://github.com/gvalkov/python-evdev#commit=$_commit")
  14 sha256sums=('SKIP')
  15
  16 pkgver() {
  17   cd $pkgname
  18   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  19 }
  20
  21 prepare() {
  22   cd $pkgname
  23 }
  24
  25 build() {
  26   cd $pkgname
  27   python -m build --wheel --no-isolation
  28 }
  29
  30 package() {
  31   cd $pkgname
  32   python -m installer --destdir="$pkgdir" dist/*.whl
  33   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE
  34 }
  35
  36 # vim:set sw=2 sts=-1 et: