python-ytmusicapi/repos/extra-any/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Pekka Ristola <pekkarr [at] protonmail [dot] com>
   3 # Contributor: Tim Schumacher <timschumi@gmx.de>
   4
   5 _pyname=ytmusicapi
   6 pkgname=python-$_pyname
   7 pkgver=1.0.2
   8 pkgrel=2
   9 pkgdesc='Unofficial API for YouTube Music'
  10 arch=(any)
  11 url='https://github.com/sigma67/ytmusicapi'
  12 license=(MIT)
  13 depends=(python-requests)
  14 makedepends=(python-build python-installer python-setuptools-scm python-wheel python-sphinx)
  15 source=(https://files.pythonhosted.org/packages/source/${_pyname::1}/$_pyname/$_pyname-$pkgver.tar.gz)
  16 sha256sums=('f798bfedd49738bece82aac15b2d97f04578ccb1572f347a350cb704df4d0e10')
  17
  18 build() {
  19   cd $_pyname-$pkgver
  20   python -m build --wheel --no-isolation
  21   make -C docs text
  22 }
  23
  24 package() {
  25   cd $_pyname-$pkgver
  26   python -m installer --destdir="$pkgdir" dist/*.whl
  27
  28   mkdir -p "$pkgdir"/usr/share/doc/$pkgname
  29   cp -r docs/build/text/* "$pkgdir"/usr/share/doc/$pkgname
  30   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
  31 }