spirv-tools/trunk/PKGBUILD

   1 # Maintainer: Laurent Carlier <lordheavym@gmail.com>
   2
   3 pkgname=spirv-tools
   4 pkgver=2022.4
   5 pkgrel=1
   6 pkgdesc="API and commands for processing SPIR-V modules"
   7 arch=('x86_64')
   8 url="https://www.khronos.org/vulkan/"
   9 license=('custom')
  10 groups=(vulkan-devel)
  11 depends=('gcc-libs' 'sh')
  12 makedepends=('cmake' 'python' 'git' 'ninja' 'spirv-headers')
  13 source=("git+https://github.com/KhronosGroup/SPIRV-Tools.git#tag=v${pkgver}")
  14 sha256sums=('SKIP')
  15
  16 build() {
  17   cd SPIRV-Tools
  18
  19   cmake \
  20       -Bbuild \
  21       -GNinja \
  22       -DCMAKE_INSTALL_PREFIX=/usr \
  23       -DCMAKE_INSTALL_LIBDIR=lib \
  24       -DCMAKE_BUILD_TYPE=None \
  25       -DSPIRV_WERROR=Off \
  26       -DBUILD_SHARED_LIBS=ON \
  27       -DSPIRV_TOOLS_BUILD_STATIC=OFF \
  28       -DSPIRV-Headers_SOURCE_DIR=/usr
  29   ninja -C build
  30 }
  31
  32 check() {
  33   cd SPIRV-Tools
  34   ninja -C build test
  35 }
  36
  37 package() {
  38   cd SPIRV-Tools
  39
  40   DESTDIR="${pkgdir}" ninja -C build install
  41
  42   install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
  43 }