vinagre/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Allan McRae <mcrae_allan@hotmail.com>
   4 # Contributor: lp76 <l.peduto@gmail.com>
   5
   6 pkgname=vinagre
   7 pkgver=3.22.0+r160+gc86e114
   8 pkgrel=1
   9 epoch=1
  10 pkgdesc="A VNC Client for the GNOME desktop"
  11 url="https://wiki.gnome.org/Apps/Vinagre"
  12 arch=(x86_64)
  13 license=(GPL)
  14 depends=(libsecret gtk-vnc vte3 telepathy-glib avahi spice-gtk3 gnutls freerdp)
  15 makedepends=(docbook-xsl intltool openssh itstool spice-protocol vala
  16              gnome-common appstream-glib git gobject-introspection)
  17 optdepends=('openssh: SSH plugin')
  18 options=(debug)
  19 _commit=c86e114efe31381bff3cad008e9f2cd84a83a803  # master
  20 source=("git+https://gitlab.gnome.org/GNOME/vinagre.git#commit=$_commit")
  21 b2sums=('SKIP')
  22
  23 pkgver() {
  24   cd $pkgname
  25   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  26 }
  27
  28 prepare() {
  29   cd $pkgname
  30   NOCONFIGURE=1 ./autogen.sh
  31 }
  32
  33 build() {
  34   cd $pkgname
  35   CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  36   ./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib/$pkgname \
  37     --enable-rdp --enable-spice --enable-compile-warnings=minimum
  38   make
  39 }
  40
  41 package() {
  42   cd $pkgname
  43   make DESTDIR="$pkgdir" install
  44 }
  45
  46 # vim:set sw=2 sts=-1 et: