chromaprint/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: Wieland Hoffmann <the_mineo@web.de>
   4
   5 pkgname=chromaprint
   6 pkgver=1.5.1
   7 pkgrel=4
   8 pkgdesc="Library for extracting fingerprints from any audio source"
   9 url="https://acoustid.org/chromaprint"
  10 arch=('x86_64')
  11 license=('LGPL2.1' 'MIT')
  12 depends=('gcc-libs' 'glibc')
  13 makedepends=('cmake' 'ffmpeg' 'gtest')
  14 provides=('libchromaprint.so')
  15 # upstream signs with DSA key: https://github.com/acoustid/chromaprint/issues/81
  16 source=(https://github.com/acoustid/${pkgname}/archive/v$pkgver/$pkgname-$pkgver.tar.gz
  17         chromaprint-ffmpeg5.patch::https://patch-diff.githubusercontent.com/raw/acoustid/chromaprint/pull/114.patch)
  18 sha512sums=('ea16e4d2b879c15b1d9b9ec93878da8b893f1834c70942663e1d2d106c2e0a661094fe2dd3bae7a6c2a1f9d5d8fab5e0b0ba493561090cf57b2228606fad1e66'
  19             'b487c7b61dd67a2a84d51b8ead3aee58f678f1179da33b39071093af4d6fb0bdc536f8c872b0edaeefc81d4c6c9b0f4a634ab8df623b75e03b629ebd88c897b9')
  20 b2sums=('9f7f030e97d3114cf679df298d313ea826c0fb05e7e7d8a10090d0a27ed0811b380b81b29fce973e0493826c478964367396311fd0484619cb2fc4c2d8e0d4c0'
  21         '6f386ff4690e5286df7609f2211eb4edea07508eff087622aacbee81d8ca2147378a244886fb6d0951c1dca627dc022f661f68c36d155f17a8ac69e8a9287138')
  22
  23 prepare() {
  24   patch -d $pkgname-$pkgver -p1 < chromaprint-ffmpeg5.patch
  25 }
  26
  27 build() {
  28   cd "${pkgname}-${pkgver}"
  29   cmake -DCMAKE_INSTALL_PREFIX=/usr \
  30         -DCMAKE_BUILD_TYPE='None' \
  31         -DBUILD_TESTS=ON \
  32         -DBUILD_TOOLS=ON \
  33         -DGTEST_SOURCE_DIR=/usr/src/googletest/ \
  34         -Wno-dev \
  35         -B build \
  36         -S .
  37   make VERBOSE=1 -C build
  38 }
  39
  40 check() {
  41   cd "${pkgname}-${pkgver}"
  42   make VERBOSE=1 -C build check
  43 }
  44
  45 package() {
  46   depends+=('libavcodec.so' 'libavformat.so' 'libavutil.so' 'libswresample.so')
  47   cd "${pkgname}-${pkgver}"
  48   make VERBOSE=1 DESTDIR="${pkgdir}" install -C build
  49   install -vDm 644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
  50   install -vDm 644 {NEWS.txt,README.md} -t "${pkgdir}/usr/share/doc/${pkgname}"
  51 }