evolution-data-server/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=evolution-data-server
   5 pkgver=3.46.1
   6 pkgrel=2
   7 pkgdesc="Centralized access to appointments and contacts"
   8 url="https://wiki.gnome.org/Apps/Evolution"
   9 arch=(x86_64)
  10 depends=(gnome-online-accounts nss krb5 libgweather-4 libical db libphonenumber
  11          libcanberra gcr-4 webkit2gtk-{4.1,5.0})
  12 makedepends=(gperf gobject-introspection vala gtk-doc boost git cmake ninja)
  13 provides=(libcamel-1.2.so libebackend-1.2.so libebook-1.2.so libebook-contacts-1.2.so
  14           libecal-2.0.so libedata-book-1.2.so libedata-cal-2.0.so libedataserver-1.2.so
  15           libedataserverui-1.2.so libedataserverui4-1.0.so)
  16 license=(GPL)
  17 options=(debug)
  18 _commit=29cf85dd84f211cf2174dac2c714bfe7c6def679  # tags/3.46.1^0
  19 source=("git+https://gitlab.gnome.org/GNOME/evolution-data-server.git#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29 }
  30
  31 build() {
  32   cmake -S $pkgname -B build -G Ninja \
  33     -DCMAKE_INSTALL_PREFIX=/usr \
  34     -DLIBEXEC_INSTALL_DIR=/usr/lib \
  35     -DSYSCONF_INSTALL_DIR=/etc \
  36     -DENABLE_INTROSPECTION=ON \
  37     -DENABLE_VALA_BINDINGS=ON \
  38     -DENABLE_GTK_DOC=ON \
  39     -DWITH_PHONENUMBER=ON \
  40     -DWITH_GWEATHER4=ON
  41   cmake --build build
  42 }
  43
  44 check() {
  45   cd build
  46   ctest --output-on-failure --stop-on-failure
  47 }
  48
  49 package() {
  50   DESTDIR="$pkgdir" cmake --install build
  51 }
  52
  53 # vim:set sw=2 sts=-1 et: