brotli/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   3 # Contributor: Lex Black <autumn-wind at web dot de>
   4 # Contributor: TingPing <tingping@tingping.se>
   5 # Contributor: Guillaume Horel <guillaume.horel@gmail.com>
   6
   7 pkgbase=brotli
   8 pkgname=('brotli' 'python-brotli' 'brotli-testdata')
   9 _gitcommit=e61745a6b7add50d380cfd7d3883dd6c62fc2c71
  10 pkgver=1.0.9
  11 pkgrel=7
  12 pkgdesc='Generic-purpose lossless compression algorithm'
  13 url='https://github.com/google/brotli'
  14 arch=('x86_64')
  15 license=('MIT')
  16 makedepends=('git' 'glibc' 'gcc-libs' 'cmake' 'python-setuptools')
  17 source=(${pkgname}::"git+${url}#commit=${_gitcommit}")
  18 sha512sums=('SKIP')
  19
  20 prepare() {
  21   cd ${pkgbase}
  22   git cherry-pick -n 09b0992b6acb7faa6fd3b23f9bc036ea117230fc # Fix broken Libs: in pc file
  23 }
  24
  25 pkgver() {
  26   cd ${pkgbase}
  27   git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
  28 }
  29
  30 build() {
  31   cd ${pkgbase}
  32   python setup.py build
  33   cmake -B build \
  34     -DCMAKE_BUILD_TYPE=Release \
  35     -DCMAKE_INSTALL_PREFIX=/usr \
  36     -DCMAKE_INSTALL_LIBDIR=lib \
  37         -DBUILD_SHARED_LIBS=True
  38   make -C build VERBOSE=1
  39 }
  40
  41 check() {
  42   cd ${pkgbase}
  43   make test
  44   python setup.py test
  45 }
  46
  47 package_brotli() {
  48   depends=('gcc-libs' 'glibc')
  49   provides=(libbrotlicommon.so libbrotlidec.so libbrotlienc.so)
  50
  51   cd ${pkgbase}
  52   make -C build DESTDIR="$pkgdir" install
  53   local man;
  54   for man in docs/*.?; do
  55     install -Dm 644 "$man" "$pkgdir/usr/share/man/man${man##*.}/${man##*/}"
  56   done
  57   install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  58 }
  59
  60 package_python-brotli() {
  61   pkgdesc+=' - python library'
  62   depends=('python' 'glibc' 'gcc-libs')
  63
  64   cd ${pkgbase}
  65   python setup.py install --skip-build -O1 --root="$pkgdir"
  66   install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  67 }
  68
  69 package_brotli-testdata() {
  70   pkgdesc+=' - test data'
  71   depends=()
  72
  73   cd ${pkgbase}
  74   install -dm755 "$pkgdir"/usr/share/brotli
  75   cp -a tests/testdata "$pkgdir"/usr/share/brotli/
  76   install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  77 }