irqbalance/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Dan McGee <dan@archlinux.org>
   3 # Contributor: Martin Striz <ms@poruba.net>
   4
   5 pkgname=irqbalance
   6 pkgver=1.8.0
   7 pkgrel=1
   8 pkgdesc="IRQ balancing daemon for SMP systems"
   9 arch=('x86_64')
  10 url="https://github.com/irqbalance/irqbalance"
  11 license=('GPL2')
  12 backup=('etc/irqbalance.env')
  13 depends=('glibc')
  14 makedepends=('glib2' 'libcap-ng' 'ncurses' 'numactl' 'systemd' 'systemd-libs')
  15 source=("$pkgname-$pkgver.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/v$pkgver.tar.gz")
  16 sha512sums=('3d757198dbe680b010ed9233d73cbf3b4a150e6b07ef97d3e94f5fa0472a22b0b3800868634340fb413a18683ff95ff6a8f7fa51ace65d870651336479e32740')
  17 b2sums=('0181ee57c4ddbdb55e1529cfd7da4b875320eff65cb606f925f0b4f4243b51e1349d4aba38690a78d7deab6d3f55ae8d6c45af44a904f03d7127678202f288db')
  18
  19 prepare() {
  20   cd "$pkgname-$pkgver"
  21   # fix location of configuration and binary in service
  22   sed -e 's|/path/to/|/etc/|g' \
  23       -e 's|/usr/sbin|/usr/bin|g' \
  24       -i "misc/${pkgname}.service"
  25   autoreconf -vfi
  26 }
  27
  28 build() {
  29   cd "$pkgname-$pkgver"
  30   ./configure --prefix=/usr \
  31               --sbindir=/usr/bin \
  32               --with-systemd
  33   make
  34 }
  35
  36 package() {
  37   depends+=('libglib-2.0.so' 'libcap-ng.so' 'libncursesw.so' 'libnuma.so' 'libsystemd.so')
  38   cd "$pkgname-$pkgver"
  39   make install DESTDIR="$pkgdir"
  40   install -vDm 644 misc/irqbalance.service \
  41     -t "${pkgdir}/usr/lib/systemd/system/"
  42   install -vDm 644 misc/irqbalance.env -t "${pkgdir}/etc/"
  43   install -vDm 644 {AUTHORS,README.md} -t "${pkgdir}/usr/share/doc/${pkgname}"
  44 }