libasyncns/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
   2 # Contributor: Corrado Primier <bardo@aur.archlinux.org>
   3 # Contributor: Eric Belanger <belanger@astro.umontreal.ca>
   4 # Contributor: William Rea <sillywilly@gmail.com>
   5 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   6
   7 pkgname=libasyncns
   8 pkgver=0.8+3+g68cd5af
   9 pkgrel=3
  10 pkgdesc="A C library for executing name service queries asynchronously"
  11 arch=(x86_64)
  12 url="http://0pointer.de/lennart/projects/libasyncns"
  13 license=(LGPL)
  14 depends=(glibc)
  15 makedepends=(git lynx)
  16 _commit=68cd5aff1467638c086f1bedcc750e34917168e4
  17 source=("git://git.0pointer.de/libasyncns.git#commit=$_commit")
  18 md5sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe | sed 's/^v//;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27   NOCONFIGURE=1 ./bootstrap.sh
  28 }
  29
  30 build() {
  31   cd $pkgname
  32   ./configure --prefix=/usr
  33   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  34   make
  35 }
  36
  37 package() {
  38   cd $pkgname
  39   make DESTDIR="$pkgdir" install
  40 }