graphene/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=graphene
   4 pkgver=1.10.8
   5 pkgrel=1
   6 pkgdesc="A thin layer of graphic data types"
   7 url="https://ebassi.github.io/graphene/"
   8 arch=(x86_64)
   9 license=(MIT)
  10 makedepends=(git gtk-doc gobject-introspection meson glib2)
  11 checkdepends=(python-gobject python-tappy)
  12 _commit=4e2578450809c2099400cf85caf18eafcd7100aa  # tags/1.10.8^0
  13 source=("git+https://github.com/ebassi/graphene#commit=$_commit"
  14         "git+https://github.com/ebassi/mutest"
  15         no-installed-tests.diff)
  16 sha256sums=('SKIP'
  17             'SKIP'
  18             'fd7c41b25920077158d7de77f5d073e3a5a215c4d96c3b9bd016ffda615be4c4')
  19
  20 pkgver() {
  21   cd graphene
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd graphene
  27
  28   # Don't install tests
  29   git apply -3 ../no-installed-tests.diff
  30
  31   git submodule init
  32   git submodule set-url subprojects/mutest "$srcdir/mutest"
  33   git submodule update
  34 }
  35
  36 build() {
  37   arch-meson graphene build \
  38     -D gtk_doc=true \
  39     -D installed_tests=false
  40   meson compile -C build
  41 }
  42
  43 check() {
  44   meson test -C build --print-errorlogs
  45 }
  46
  47 package() {
  48   depends=(libg{lib,object}-2.0.so)
  49   provides=(libgraphene-1.0.so)
  50
  51   meson install -C build --destdir "$pkgdir"
  52   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 graphene/LICENSE.txt
  53 }
  54
  55 # vim:set sw=2 et: