python-dbusmock/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=python-dbusmock
   4 pkgver=0.28.6
   5 pkgrel=2
   6 pkgdesc="Mock D-Bus objects for tests"
   7 url="https://github.com/martinpitt/python-dbusmock"
   8 arch=(any)
   9 license=(LGPL3)
  10 depends=(python-dbus python-gobject)
  11 makedepends=(python-setuptools python-setuptools-scm python-build
  12              python-installer python-wheel git)
  13 _commit=276f54de0f653e8a37b0d0392450df3f57b0a746  # tags/0.28.6^0
  14 source=("git+https://github.com/martinpitt/python-dbusmock#commit=$_commit"
  15         0001-Fix-OBEX-PullAll-after-pathlib-conversion.patch)
  16 sha256sums=('SKIP'
  17             'd259cbecb464ad5ea782f43ca630062ffa03feb6017825a3b7ac235d910ba798')
  18
  19 # Suppress local version
  20 export SETUPTOOLS_SCM_PRETEND_VERSION="${pkgver%%+*}"
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29   git apply -3 ../0001-Fix-OBEX-PullAll-after-pathlib-conversion.patch
  30 }
  31
  32 build() {
  33   cd $pkgname
  34   python -m build --wheel --no-isolation
  35 }
  36
  37 package() {
  38   cd $pkgname
  39   python -m installer --destdir="$pkgdir" dist/*.whl
  40 }
  41
  42 # vim:set sw=2 sts=-1 et: