alacarte/repos/extra-any/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: pressh <pressh@gmail.com>
   4
   5 pkgname=alacarte
   6 pkgver=3.44.2
   7 pkgrel=1
   8 epoch=1
   9 pkgdesc="Menu editor for gnome"
  10 url="https://gitlab.gnome.org/GNOME/alacarte"
  11 arch=(any)
  12 license=(LGPL)
  13 depends=(gnome-menus python-gobject python-cairo gtk3)
  14 makedepends=(libxslt docbook-xsl git)
  15 options=(debug)
  16 _commit=d17e9b08324a9958f734c0756e6d185c16135f55  # tags/3.44.2^0
  17 source=("git+https://gitlab.gnome.org/GNOME/alacarte.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd alacarte
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd alacarte
  27   NOCONFIGURE=1 ./autogen.sh
  28 }
  29
  30 build() {
  31   cd alacarte
  32   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  33   make
  34 }
  35
  36 package() {
  37   cd alacarte
  38   make DESTDIR="$pkgdir" install
  39
  40   python -m compileall -d /usr "$pkgdir/usr"
  41   python -O -m compileall -d /usr "$pkgdir/usr"
  42 }