alacarte/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: pressh <pressh@gmail.com>
   4
   5 pkgname=alacarte
   6 pkgver=3.44.2
   7 pkgrel=1
   8 epoch=1
   9 pkgdesc="Menu editor for gnome"
  10 url="https://gitlab.gnome.org/GNOME/alacarte"
  11 arch=(any)
  12 license=(LGPL)
  13 depends=(gnome-menus python-gobject python-cairo gtk3)
  14 makedepends=(libxslt docbook-xsl git)
  15 _commit=d17e9b08324a9958f734c0756e6d185c16135f55  # tags/3.44.2^0
  16 source=("git+https://gitlab.gnome.org/GNOME/alacarte.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd alacarte
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd alacarte
  26   NOCONFIGURE=1 ./autogen.sh
  27 }
  28
  29 build() {
  30   cd alacarte
  31   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  32   make
  33 }
  34
  35 package() {
  36   cd alacarte
  37   make DESTDIR="$pkgdir" install
  38
  39   python -m compileall -d /usr "$pkgdir/usr"
  40   python -O -m compileall -d /usr "$pkgdir/usr"
  41 }